SOLVED Two different Win10 Product Keys

[Robert Hall]

Hi,
In an attempt to document the W10 prod key on all of my systems after losing a key during a backup recovery operation that did not go very well, I used both Belarc Advisor and SPECCY to dig them out. They, however, each report a different key when run on the same system. I don't have the original keys after so many upgrades over the years; now I don't know what do believe are the correct keys. Can someone throw some light on why these 2 programs report 2 different Win10 keys after the install? Where in Win10 can I find that info w/o resorting to other software.
Thanks for your help from a computer lightweight. Robert Hall

 

[Regedit32]

You can use a Visual basic script to obtain your Product key:

Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0
   
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If    
   

    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
   
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

Copy & paste the above code into a Notepad document, then click File | Save as and name it pk.vbs

To run it, simply double-left-click on the file you saved.

Alternatively, if your computer originally came with Windows 10 installed on it, you can use PowerShell to access the original product key that would have been stored within your firmware.

1. Right-click on Start and select Windows PowerShell (Admin) When prompted click yes to the UAC prompt.
2. In the PowerShell console type or copy & paste the following command, then press Enter to execute.

wmic path SoftwareLicensingService get OA3xOriginalProductKey​

As to why third party apps are finding difference product keys, I am unsure. If your computer is second hand then perhaps its finding an original one, plus your new one, or perhaps at some time you paid for a different edition of Windows and thus have a second product key, but you still have a Recovery partition with the original edition too.

Regards,

Regedit32

Source for Script: https://gist.github.com/craigtp/dda7d0fce891a087a962d29be960f1da
Credit: Craig

 

[Robert Hall]

RegEdit32

Thank you for the VBS script PK. With that I was able to confirm that the utility BELARC Advisor did report
the correct Key and the utility SPECCY did not.

On a side note, my 4 systems all had a legal purchased copy of W7 prior to the free MS upgrade to W10.
Currently none of my system's reported Key is the original W7 key for that system.
At this time my 2 W10 Home systems BOTH report the same key, and similarly, my 2 W10 Pro systems
report a different key but BOTH report the same key. It makes me think that the W10 Home free upgrade
systems all have the same key and all W10 Pro free upgrades also share the same key,
but different from the Home version. Maybe someone might venture an opinion and fill in the blanks for me.
Thanks again for your help.

 

[Grizzly]

You are right about those keys. These are only valid for upgrade in regards with a digital license. That means a hardware token is stored on the Microsoft servers from any pc that uses these upgrade keys.
If you need to change the pc significantly (e.g. motherboard) then you will loose that token and HAVE to buy a new license.

 

[Robert Hall]

Thank you Grizzly. Now I have to figure out how to reactivate one of my systems-- which MS no longer will do--when all I did was upgrade my HD to a larger one. The Restore to the new drive from a Recovery Disk + Image did not end well, and I am still going in circles to get it reactivated. I will report progress later on. Robert Hall